ca-certificates/repos/core-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Pierre Schmitz <pierre@archlinux.de>
   3
   4 pkgbase=ca-certificates
   5 pkgname=(ca-certificates-utils ca-certificates)
   6 pkgver=20220905
   7 pkgrel=1
   8 pkgdesc="Common CA certificates"
   9 url="https://src.fedoraproject.org/rpms/ca-certificates"
  10 arch=(any)
  11 license=(GPL)
  12 makedepends=(asciidoc p11-kit)
  13 source=(update-ca-trust update-ca-trust.8.txt 40-update-ca-trust.hook
  14         README.{etc,etcssl,extr,java,src,usr})
  15 sha256sums=('ba98e00f80f94e2648b66252119d1b0da2339b8c83860cd69738e5c4e2d0fcc3'
  16             '7123fcc59bcf50dac66606c8d1b2669106e88579375f98b12e8ae06d96eb7763'
  17             '3a3833ebd6f9cdef2e534a273653f973a4354d4f9368577d0d73236b014b7748'
  18             'e14e00e2e862ac0da3fc77c265e58ee3dcc9c776280639323b8ee804c9d0f69a'
  19             'c94462e3addd6328d3fda77436bfb9d39099dd9dbfb6bafd5941d743cb0aaf10'
  20             'badc9c0ec9324dae0889b8f5a5c70f14416507234b9cafcb84ecb99a2b67fc78'
  21             '5300660244bb621cbbb7fd3646bd33f7a5fad6801580593d8d5b3cf6fa9a158d'
  22             'eba594055ad00cb0b73fc2b0eb8aa4845e5cb4eb42aac88e5f1429213b9e301f'
  23             '3493832f17595d6d5a6711e5b188ef36f040e0caec7e0f3303623550ed6943cc')
  24
  25 build() {
  26   a2x -v -f manpage update-ca-trust.8.txt
  27 }
  28
  29 package_ca-certificates-utils() {
  30   pkgdesc+=" (utilities)"
  31   depends=(bash coreutils findutils 'p11-kit>=0.24.0')
  32   provides=(ca-certificates ca-certificates-java)
  33   conflicts=(ca-certificates-java)
  34   replaces=(ca-certificates-java)
  35   install=ca-certificates-utils.install
  36
  37   install -Dt "$pkgdir/usr/bin" update-ca-trust
  38   install -Dt "$pkgdir/usr/share/man/man8" -m644 update-ca-trust.8
  39   install -Dt "$pkgdir/usr/share/libalpm/hooks" -m644 *.hook
  40
  41   # Trust source directories
  42   install -Dm644 README.etc "$pkgdir/etc/$pkgbase/README"
  43   install -Dm644 README.src "$pkgdir/etc/$pkgbase/trust-source/README"
  44   install -Dm644 README.usr "$pkgdir/usr/share/$pkgbase/trust-source/README"
  45   install -d "$pkgdir"/{etc,usr/share}/$pkgbase/trust-source/{anchors,blocklist}
  46
  47   # Directories used by update-ca-trust (aka "trust extract-compat")
  48   install -Dm644 README.etcssl "$pkgdir/etc/ssl/README"
  49   install -Dm644 README.java   "$pkgdir/etc/ssl/certs/java/README"
  50   install -Dm644 README.extr   "$pkgdir/etc/$pkgbase/extracted/README"
  51
  52   # Compatibility link for OpenSSL using /etc/ssl as CAdir
  53   # Used in preference to the individual links in /etc/ssl/certs
  54   ln -sr "$pkgdir/etc/$pkgbase/extracted/tls-ca-bundle.pem" "$pkgdir/etc/ssl/cert.pem"
  55
  56   # Compatibility link for legacy bundle (Debian)
  57   ln -sr "$pkgdir/etc/$pkgbase/extracted/tls-ca-bundle.pem" "$pkgdir/etc/ssl/certs/ca-certificates.crt"
  58
  59   # Compatibility link for legacy bundle (RHEL/Fedora)
  60   ln -sr "$pkgdir/etc/$pkgbase/extracted/tls-ca-bundle.pem" "$pkgdir/etc/ssl/certs/ca-bundle.crt"
  61 }
  62
  63 package_ca-certificates() {
  64   pkgdesc+=" (default providers)"
  65   depends=(ca-certificates-mozilla)
  66   conflicts=('ca-certificates-cacert<=20140824-4')
  67   replaces=("${conflicts[@]}")
  68 }
  69
  70 # vim:set sw=2 sts=-1 et: