gnome-text-editor/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Fabian Bornschein <fabiscafe-cat-mailbox-dog-org>
   3
   4 pkgname=gnome-text-editor
   5 pkgver=44.0
   6 pkgrel=1
   7 pkgdesc="A simple text editor for the GNOME desktop"
   8 url="https://gitlab.gnome.org/GNOME/gnome-text-editor"
   9 arch=(x86_64)
  10 license=(GPL3)
  11 depends=(
  12   editorconfig-core-c
  13   enchant
  14   glib2
  15   gtksourceview5
  16   libadwaita
  17 )
  18 makedepends=(
  19   appstream-glib
  20   git
  21   meson
  22   yelp-tools
  23 )
  24 groups=(gnome)
  25 _commit=2ed7d45ff481f5d0a2cda54e0ec75ce5a823f40e  # tags/44.0^0
  26 source=("git+https://gitlab.gnome.org/GNOME/gnome-text-editor.git#commit=$_commit")
  27 b2sums=('SKIP')
  28
  29 pkgver() {
  30   cd $pkgname
  31   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  32 }
  33
  34 prepare() {
  35   cd $pkgname
  36 }
  37
  38 build() {
  39   local meson_options=(
  40     -D bugreport_url="https://bugs.archlinux.org/"
  41   )
  42
  43   arch-meson $pkgname build "${meson_options[@]}"
  44   meson compile -C build
  45 }
  46
  47 check() {
  48   meson test -C build --print-errorlogs
  49 }
  50
  51 package() {
  52   meson install -C build --destdir "$pkgdir"
  53 }
  54
  55 # vim:set sw=2 sts=-1 et: