java-jline/trunk/PKGBUILD

   1 # Maintainer: Guillaume ALAUX <guillaume@archlinux.org>
   2 _libname=jline
   3 pkgname=("java-${_libname}")
   4 pkgver=1.0
   5 pkgrel=7
   6 pkgdesc="Java library for handling console input"
   7 arch=('any')
   8 url="https://jline.github.io/"
   9 license=('BSD')
  10 makedepends=('maven' 'java-environment=8')
  11 checkdepends=('maven')
  12 source=(https://downloads.sourceforge.net/project/${_libname}/${_libname}/${pkgver}/${_libname}-${pkgver}.zip)
  13 sha256sums=('761458d1541a44e678b3847917116a90001cf5cd22287c24c55dcf2c69ec73ca')
  14 _M2_REPO=$(mktemp -d)
  15
  16 build() {
  17   cd "${srcdir}/${_libname}-${pkgver}/src"
  18
  19   mvn -Dmaven.repo.local=${_M2_REPO} \
  20     clean \
  21     package \
  22     -Dmaven.test.skip=true
  23 }
  24
  25 check() {
  26   cd "${srcdir}/${_libname}-${pkgver}/src"
  27
  28   mvn -Dmaven.repo.local=${_M2_REPO} \
  29     test
  30 }
  31
  32 package() {
  33   depends=('java-runtime-headless')
  34
  35   cd "${srcdir}/${_libname}-${pkgver}"
  36
  37   install -Dm644 src/target/${_libname}-${pkgver}.jar \
  38                  "${pkgdir}"/usr/share/java/${_libname}-${pkgver}.jar
  39   ln -s ${_libname}-${pkgver}.jar "${pkgdir}"/usr/share/java/${_libname}.jar
  40
  41   install -Dm644 LICENSE.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
  42 }