libnotify/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=libnotify
   5 pkgname=(
   6   libnotify
   7   libnotify-docs
   8 )
   9 pkgver=0.8.2
  10 pkgrel=1
  11 pkgdesc="Library for sending desktop notifications"
  12 url="https://gitlab.gnome.org/GNOME/libnotify"
  13 arch=(x86_64)
  14 license=(LGPL)
  15 depends=(gdk-pixbuf2)
  16 makedepends=(
  17   docbook-xsl
  18   gi-docgen
  19   git
  20   gobject-introspection
  21   gtk3
  22   meson
  23   xmlto
  24 )
  25 _commit=69aff6e5fa2842e00b409c348bd73188548828b3  # tags/0.8.2^0
  26 source=("git+$url.git#commit=$_commit")
  27 sha256sums=('SKIP')
  28
  29 pkgver() {
  30   cd $pkgname
  31   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  32 }
  33
  34 prepare() {
  35   cd $pkgname
  36 }
  37
  38 build() {
  39   arch-meson $pkgname build
  40   meson compile -C build
  41 }
  42
  43 check() {
  44   meson test -C build --print-errorlogs
  45 }
  46
  47 package_libnotify() {
  48   depends+=(
  49     libg{lib,object,io}-2.0.so
  50     libgdk_pixbuf-2.0.so
  51   )
  52   provides=(libnotify.so)
  53
  54   meson install -C build --destdir "$pkgdir"
  55
  56   mkdir -p doc/usr/share
  57   mv {"$pkgdir",doc}/usr/share/doc
  58 }
  59
  60 package_libnotify-docs() {
  61   pkgdesc+=" (documentation)"
  62   depends=()
  63
  64   mv doc/* "$pkgdir"
  65 }
  66
  67 # vim:set sw=2 sts=-1 et: