networkmanager-openconnect/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=networkmanager-openconnect
   5 pkgver=1.2.8
   6 pkgrel=2
   7 pkgdesc="NetworkManager VPN plugin for OpenConnect"
   8 url="https://wiki.gnome.org/Projects/NetworkManager"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(libnm libsecret openconnect libopenconnect.so)
  12 makedepends=(libnma libnma-gtk4 intltool python git)
  13 optdepends=('libnma: GUI support (GTK 3)'
  14             'libnma-gtk4: GUI support (GTK 4)')
  15 _commit=6eaa0604da8f1927db18a315dba7a3eaff4ec56e  # tags/1.2.8^0
  16 source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-openconnect.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd NetworkManager-openconnect
  21   git describe --tags | sed 's/-dev/dev/;s/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd NetworkManager-openconnect
  26   intltoolize --automake --copy
  27   autoreconf -fvi
  28 }
  29
  30 build() {
  31   cd NetworkManager-openconnect
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  33     --libexecdir=/usr/lib --disable-static --with-gtk4
  34   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  35   make
  36 }
  37
  38 package() {
  39   cd NetworkManager-openconnect
  40   make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
  41   echo 'u nm-openconnect - "NetworkManager OpenConnect"' |
  42     install -Dm644 /dev/stdin "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
  43 }
  44
  45 # vim:set sw=2 et: