xfce4-sensors-plugin/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: Andreas Radke <andyrtr@archlinux.org>
   3 # Contributor: Merk Matthias <macem@chello.at>
   4
   5 pkgname=xfce4-sensors-plugin
   6 pkgver=1.4.4
   7 pkgrel=1
   8 pkgdesc="Sensors plugin for the Xfce panel"
   9 arch=('x86_64')
  10 url="https://docs.xfce.org/panel-plugins/xfce4-sensors-plugin"
  11 license=('GPL2')
  12 groups=('xfce4-goodies')
  13 depends=('xfce4-panel' 'lm_sensors' 'libnotify' 'hicolor-icon-theme')
  14 makedepends=('intltool' 'hddtemp' 'netcat')
  15 optdepends=('hddtemp: for monitoring the temperature of hard drives')
  16 source=(https://archive.xfce.org/src/panel-plugins/$pkgname/${pkgver%.*}/$pkgname-$pkgver.tar.bz2)
  17 sha256sums=('6c1605a738e5df40e084d08ac93f962cd445093396de1e9bfadc7ab4588c36b6')
  18
  19 build() {
  20   cd $pkgname-$pkgver
  21
  22   ./configure \
  23     --prefix=/usr \
  24     --sysconfdir=/etc \
  25     --localstatedir=/var \
  26     --disable-pathchecks \
  27     --disable-debug
  28   make
  29 }
  30
  31 package() {
  32   cd $pkgname-$pkgver
  33   make DESTDIR="$pkgdir" install
  34 }
  35
  36 # vim:set ts=2 sw=2 et: