eog/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgbase=eog
   5 pkgname=(eog eog-docs)
   6 pkgver=42.3
   7 pkgrel=1
   8 pkgdesc="Eye of Gnome: An image viewing and cataloging program"
   9 url="https://wiki.gnome.org/Apps/EyeOfGnome"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(gnome-desktop libexif lcms2 exempi libpeas librsvg libhandy)
  13 makedepends=(gobject-introspection gi-docgen git meson yelp-tools systemd)
  14 options=(debug)
  15 _commit=b38fb1f0048b086100ab9ff5c0b2e18142880e8a  # tags/42.3^0
  16 source=("git+https://gitlab.gnome.org/GNOME/eog.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd eog
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 build() {
  25   arch-meson eog build -D gtk_doc=true -D libportal=false
  26   meson compile -C build
  27 }
  28
  29 check() {
  30   meson test -C build --print-errorlogs
  31 }
  32
  33 package_eog() {
  34   optdepends=('eog-plugins: Additional features')
  35   groups=(gnome)
  36
  37   meson install -C build --destdir "$pkgdir"
  38
  39   mkdir -p doc/usr/share
  40   mv {"$pkgdir",doc}/usr/share/gtk-doc
  41 }
  42
  43 package_eog-docs() {
  44   pkgdesc+=" (documentation)"
  45   depends=()
  46
  47   mv doc/* "$pkgdir"
  48 }