libhandy/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgbase=libhandy
   5 pkgname=(libhandy libhandy-docs)
   6 pkgver=1.6.3
   7 pkgrel=1
   8 pkgdesc="Library full of GTK+ widgets for mobile phones"
   9 url="https://gitlab.gnome.org/GNOME/libhandy"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(glib2 gtk3)
  13 makedepends=(git gobject-introspection meson vala glade gi-docgen)
  14 checkdepends=(xorg-server-xvfb)
  15 options=(debug)
  16 _commit=2885c314c9c84037b6fe55ead6a232e60ebfc9c5  # tags/1.6.3^0
  17 source=("git+https://gitlab.gnome.org/GNOME/libhandy.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd libhandy
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd libhandy
  27 }
  28
  29 build() {
  30   arch-meson libhandy build \
  31     -D gtk_doc=true
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   dbus-run-session xvfb-run -s '-nolisten local' \
  37     meson test -C build --print-errorlogs
  38 }
  39
  40 package_libhandy() {
  41   provides=(libhandy-1.so)
  42
  43   meson install -C build --destdir "$pkgdir"
  44
  45   mkdir -p doc/usr/share
  46   mv {"$pkgdir",doc}/usr/share/doc
  47 }
  48
  49 package_libhandy-docs() {
  50   pkgdesc+=" (documentation)"
  51   depends=()
  52
  53   mv doc/* "$pkgdir"
  54 }
  55
  56 # vim:set sw=2 et: