libpagemaker/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: AndyRTR <andyrtr@archlinux.org>
   2
   3 pkgname=libpagemaker
   4 pkgver=0.0.4
   5 pkgrel=3
   6 pkgdesc="a library that parses the file format of Aldus/Adobe PageMaker documents"
   7 arch=('x86_64')
   8 url="https://wiki.documentfoundation.org/DLP/Libraries/libpagemaker"
   9 license=('MPL')
  10 source=(https://dev-www.libreoffice.org/src/${pkgname}/${pkgname}-${pkgver}.tar.xz
  11         libpagemaker-0.0.4-const-ref-exception.patch)
  12 depends=('librevenge')
  13 makedepends=('boost' 'doxygen')
  14 sha256sums=('66adacd705a7d19895e08eac46d1e851332adf2e736c566bef1164e7a442519d'
  15             '91d9ce17b04e2fb5009967bb38da3405cb231b05c2cb29e204aaab328a58f7e2')
  16
  17 prepare() {
  18   cd ${pkgname}-${pkgver}
  19   # fix build - https://bugs.archlinux.org/task/62165
  20   patch -Np1 -i ../libpagemaker-0.0.4-const-ref-exception.patch
  21 }
  22
  23 build() {
  24   cd ${pkgname}-${pkgver}
  25   ./configure --prefix=/usr
  26   make
  27 }
  28
  29 check() {
  30   cd ${pkgname}-${pkgver}
  31   make check
  32 }
  33
  34 package() {
  35   cd ${pkgname}-${pkgver}
  36   make DESTDIR="${pkgdir}" install
  37   install -Dm644 COPYING "${pkgdir}/usr/share/licenses/${pkgname}/COPYING"
  38 }
  39