link-grammar/trunk/PKGBUILD

   1 # Maintainer: Giovanni Scafora <giovanni@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=link-grammar
   5 pkgver=5.10.2
   6 pkgrel=4
   7 pkgdesc="A Grammar Checking library"
   8 arch=('x86_64')
   9 url="https://www.abisource.com/projects/link-grammar/"
  10 license=('LGPL')
  11 depends=('hunspell' 'sqlite' 'libedit')
  12 makedepends=('python' 'swig' 'apache-ant' 'java-environment=11')
  13 options=('!makeflags')
  14 source=(https://www.abisource.com/downloads/${pkgname}/${pkgver}/${pkgname}-${pkgver}.tar.gz{,.asc})
  15 validpgpkeys=('6407453C98BECC19ADB03D82EB6AA534E0C0651C'
  16               '8305252160000B5E89843F5464A99A8201045933') # Linas Vepstas <linasvepstas@gmail.com>
  17 sha256sums=('28cec752eaa0e3897ae961333b6927459f8b69fefe68c2aa5272983d7db869b6'
  18             'SKIP')
  19
  20 prepare() {
  21   cd "${srcdir}/${pkgname}-${pkgver}"
  22
  23   # Fix build with Python 3.10
  24   sed -i '/test -n "$lg_python_unusable" && PythonFound=no/d' configure
  25 }
  26
  27 build() {
  28   cd "${srcdir}/${pkgname}-${pkgver}"
  29
  30   ./configure --prefix=/usr
  31
  32   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  33   make
  34 }
  35
  36 package() {
  37   cd "${srcdir}/${pkgname}-${pkgver}"
  38
  39   make DESTDIR="${pkgdir}" install
  40 }