mdadm/trunk/PKGBUILD

   1 # Maintainer: Tobias Powalowski <tpowa@archlinux.org>
   2 # Contributor: Judd Vinet <jvinet@zeroflux.org>
   3
   4 pkgname=mdadm
   5 pkgver=4.2
   6 pkgrel=2
   7 pkgdesc='A tool for managing/monitoring Linux md device arrays, also known as Software RAID'
   8 arch=('x86_64')
   9 license=('GPL')
  10 url='https://git.kernel.org/pub/scm/utils/mdadm'
  11 makedepends=('git')
  12 depends=('glibc' 'systemd')
  13 optdepends=('bash: mdcheck')
  14 replaces=('raidtools')
  15 backup=('etc/mdadm.conf')
  16 validpgpkeys=('6A86B80E1D22F21D0B26BA75397D82E0531A9C91') # Jes Sorensen
  17 source=("git+https://git.kernel.org/pub/scm/utils/mdadm/mdadm.git#tag=${pkgname}-${pkgver}?signed"
  18         'disable-werror.patch'
  19         'mdadm.conf'
  20         'mdadm_udev_install')
  21 sha256sums=('SKIP'
  22             '85c98b8fe880bdd365fc0e400af10c2e5d0c439d338e055f66c16162f9282846'
  23             '4ce1e90690282f98e4828e11576fbd61be65e97a2cdae6c7eac7035ea5ee53e5'
  24             'b6782029bdae2d7f87ea0e332bb90f72a7792e933580e37602e81e2f1bb82a9c')
  25 prepare() {
  26   cd mdadm
  27   patch -Np0 -i ${srcdir}/disable-werror.patch
  28 }
  29
  30 build() {
  31   cd mdadm
  32
  33   make CXFLAGS="$CFLAGS" BINDIR=/usr/bin UDEVDIR=/usr/lib/udev
  34 }
  35
  36 package() {
  37   cd mdadm
  38
  39   make INSTALL=/usr/bin/install BINDIR=/usr/bin DESTDIR="$pkgdir" UDEVDIR=/usr/lib/udev install
  40   make SYSTEMD_DIR="$pkgdir"/usr/lib/systemd/system install-systemd
  41   install -D -m644 ../mdadm.conf "$pkgdir"/etc/mdadm.conf
  42   install -D -m644 ../mdadm_udev_install "$pkgdir"/usr/lib/initcpio/install/mdadm_udev
  43   install -D -m755 misc/mdcheck "$pkgdir"/usr/share/mdadm/mdcheck
  44   ln -s mdadm_udev "$pkgdir"/usr/lib/initcpio/install/mdadm
  45 }