pyqt5/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   3 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   4 # Contributor: Yichao Yu <yyc1992@gmail.com>
   5 # Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
   6 # Contributor: riai <riai@bigfoot.com> Ben <ben@benmazer.net>
   7
   8 pkgbase=pyqt5
   9 pkgname=('python-pyqt5')
  10 pkgdesc="A set of Python bindings for the Qt5 toolkit"
  11 pkgver=5.15.7
  12 pkgrel=1
  13 arch=('x86_64')
  14 url="https://riverbankcomputing.com/software/pyqt/intro"
  15 license=('GPL')
  16 groups=(pyqt5)
  17 depends=('python-pyqt5-sip' 'qt5-base')
  18 optdepends=('python-opengl: enable OpenGL 3D graphics in PyQt applications'
  19             'python-dbus: for python-dbus mainloop support'
  20             'qt5-multimedia: QtMultimedia, QtMultimediaWidgets'
  21             'qt5-tools: QtHelp, QtDesigner'
  22             'qt5-svg: QtSvg'
  23             'qt5-webkit: QtWebKit, QtWebKitWidgets'
  24             'qt5-xmlpatterns: QtXmlPatterns'
  25             'qt5-declarative: QtQml, qmlplugin'
  26             'qt5-serialport: QtSerialPort'
  27             'qt5-websockets: QtWebSockets'
  28             'qt5-connectivity: QtNfc, QtBluetooth'
  29             'qt5-x11extras: QtX11Extras'
  30             'qt5-remoteobjects: QtRemoteObjects'
  31             'qt5-speech: QtTextToSpeech'
  32             'qt5-quick3d: QtQuick3D')
  33 provides=(qt5-python-bindings)
  34 makedepends=('sip' 'pyqt-builder' 'python-opengl' 'python-dbus'
  35              'qt5-connectivity' 'qt5-multimedia' 'qt5-tools' 'qt5-serialport' 'qt5-speech' 'qt5-svg'
  36              'qt5-webkit' 'qt5-websockets' 'qt5-x11extras' 'qt5-xmlpatterns' 'qt5-remoteobjects' 'qt5-quick3d')
  37 conflicts=('pyqt5-common')
  38 source=("https://pypi.python.org/packages/source/P/PyQt5/PyQt5-$pkgver.tar.gz")
  39 sha256sums=('755121a52b3a08cb07275c10ebb96576d36e320e572591db16cfdbc558101594')
  40 options=(debug)
  41
  42 build() {
  43   cd PyQt5-$pkgver
  44   sip-build \
  45     --confirm-license \
  46     --no-make \
  47     --api-dir /usr/share/qt/qsci/api/python
  48   cd build
  49   make
  50 }
  51
  52 package_python-pyqt5(){
  53   cd PyQt5-$pkgver/build
  54   make INSTALL_ROOT="$pkgdir" install -j1
  55
  56   # Remove unused py2 version of uic modules:
  57   rm -r "$pkgdir"/usr/lib/python*/site-packages/PyQt5/uic/port_v2
  58
  59   # compile Python bytecode
  60   python -m compileall -d / "$pkgdir"/usr/lib
  61   python -O -m compileall -d / "$pkgdir"/usr/lib
  62 }