wpebackend-fdo/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=wpebackend-fdo
   4 pkgver=1.12.0
   5 pkgrel=2
   6 pkgdesc="Freedesktop.org backend for WPE WebKit"
   7 url="https://wpewebkit.org"
   8 arch=(x86_64)
   9 license=(custom)
  10 depends=(libwpe glib2 libegl wayland libepoxy)
  11 makedepends=(mesa wayland-protocols git meson)
  12 options=(debug)
  13 _commit=1b35ae0d8f32e32431da494d3389c5b1a8812cab  # tags/1.12.0^0
  14 source=("git+https://github.com/Igalia/WPEBackend-fdo#commit=$_commit")
  15 sha256sums=('SKIP')
  16 validpgpkeys=('5AA3BC334FD7E3369E7C77B291C559DBE4C9123B') # Adrián Pérez de Castro <aperez@igalia.com>
  17
  18 pkgver() {
  19   cd WPEBackend-fdo
  20   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd WPEBackend-fdo
  25 }
  26
  27 build() {
  28   arch-meson WPEBackend-fdo build
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   depends+=(libwpe-1.0.so libg{lib,object,io}-2.0.so)
  38   provides+=(libWPEBackend-fdo-1.0.so)
  39
  40   meson install -C build --destdir "$pkgdir"
  41   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 WPEBackend-fdo/COPYING
  42 }
  43
  44 # vim:set sw=2 et: