cogl/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=cogl
   5 pkgver=1.22.8
   6 pkgrel=2
   7 pkgdesc="An object oriented GL/GLES Abstraction/Utility Layer"
   8 url="https://blogs.gnome.org/clutter/"
   9 arch=(x86_64)
  10 license=(GPL2)
  11 depends=(mesa libdrm libxext libxdamage libxcomposite gdk-pixbuf2 pango
  12          libxrandr)
  13 makedepends=(gobject-introspection git gtk-doc)
  14 provides=(libcogl.so libcogl-{gles2,pango,path}.so)
  15 _commit=c2e25cef6bd7b3f12c8625f82956388e419cd046  # tags/1.22.8^0
  16 source=("git+https://gitlab.gnome.org/GNOME/cogl.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd cogl
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd cogl
  26   NOCONFIGURE=1 ./autogen.sh
  27 }
  28
  29 build() {
  30   cd cogl
  31   ./configure --prefix=/usr \
  32     --enable-gles2 \
  33     --enable-{kms,wayland}-egl-platform \
  34     --enable-wayland-egl-server
  35
  36   # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  37   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  38
  39   make
  40 }
  41
  42 package() {
  43   cd cogl
  44   make DESTDIR="$pkgdir" install
  45 }
  46
  47 # vim:set sw=2 et: