gnome-logs/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-logs
   4 pkgver=43.0
   5 pkgrel=1
   6 pkgdesc="A log viewer for the systemd journal"
   7 url="https://wiki.gnome.org/Apps/Logs"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(systemd gtk4 libadwaita gsettings-desktop-schemas)
  11 makedepends=(appstream-glib git meson yelp-tools)
  12 groups=(gnome)
  13 _commit=3fa0b8a7f734e6adf865cc5df673f6a74809b56d  # tags/43.0^0
  14 source=("git+https://gitlab.gnome.org/GNOME/gnome-logs.git#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/^gnome-logs-//;s/[^-]*-g/r&/;s/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24 }
  25
  26 build() {
  27   local meson_options=(
  28     -D man=true
  29   )
  30
  31   arch-meson $pkgname build "${meson_options[@]}"
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41 }
  42
  43 # vim:set sw=2 sts=-1 et: