gtksourceview4/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3 # Contributor: Ionut Biru <ibiru@archlinux.org>
   4
   5 pkgname=gtksourceview4
   6 pkgver=4.8.4
   7 pkgrel=1
   8 pkgdesc="A text widget adding syntax highlighting and more to GNOME"
   9 url="https://wiki.gnome.org/Projects/GtkSourceView"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(gtk3 libxml2)
  13 makedepends=(gobject-introspection vala gtk-doc glade yelp-tools git meson)
  14 checkdepends=(xorg-server-xvfb)
  15 provides=(libgtksourceview-${pkgver%%.*}.so)
  16 options=(debug)
  17 _commit=7fd3adb3134bbec167167bb6400e018e4f781eb9  # tags/4.8.4^0
  18 source=("git+https://gitlab.gnome.org/GNOME/gtksourceview.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd gtksourceview
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd gtksourceview
  28 }
  29
  30 build() {
  31   local meson_options=(
  32     -D glade_catalog=true
  33     -D gtk_doc=true
  34   )
  35
  36   arch-meson gtksourceview build "${meson_options[@]}"
  37   meson compile -C build
  38 }
  39
  40 check() {
  41   dbus-run-session xvfb-run -s '-nolisten local' \
  42     meson test -C build --print-errorlogs
  43 }
  44
  45 package() {
  46   meson install -C build --destdir "$pkgdir"
  47 }
  48
  49 # vim:set sw=2 sts=-1 et: