libsodium/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: namelessjon <jonathan.stott@gmail.com>
   3 # Contributor: Alessio Sergi <asergi at archlinux dot us>
   4
   5 pkgname=libsodium
   6 pkgver=1.0.18
   7 pkgrel=2
   8 pkgdesc="P(ortable|ackageable) NaCl-based crypto library"
   9 arch=('x86_64')
  10 url="https://github.com/jedisct1/libsodium"
  11 license=('custom:ISC')
  12 depends=('glibc')
  13 makedepends=('minisign')
  14 source=("https://download.libsodium.org/libsodium/releases/libsodium-$pkgver.tar.gz"{,.minisig})
  15 sha512sums=('17e8638e46d8f6f7d024fe5559eccf2b8baf23e143fadd472a7d29d228b186d86686a5e6920385fe2020729119a5f12f989c3a782afbd05a8db4819bb18666ef'
  16             'e0cf76872079c295d71cf60d7bf95dc67d2285f4786b8bc47bbc6c0adbef05f6e0cb14a5100b8a1b7115eeed70cfd2f6574e198df620bbe60cf884187e6a903f')
  17 _validminisignkey='RWQf6LRCGA9i53mlYecO4IzT51TGPpvWucNSCh1CBM0QTaLn73Y7GFO3'
  18
  19 prepare() {
  20   minisign -Vm $pkgname-$pkgver.tar.gz -P $_validminisignkey
  21 }
  22
  23 build() {
  24   cd "$pkgname-$pkgver"
  25
  26   ./configure --prefix=/usr
  27   make
  28 }
  29
  30 check() {
  31   cd "$pkgname-$pkgver"
  32   make check
  33 }
  34
  35 package() {
  36   cd "$pkgname-$pkgver"
  37   make DESTDIR="$pkgdir" install
  38
  39   # install license
  40   install -d -m 755 "$pkgdir/usr/share/licenses/$pkgname"
  41   install -m 644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  42 }
  43
  44 # vim:set ts=2 sw=2 et: