libtheora/trunk/PKGBUILD

   1 # Maintainer: Tom Killian <tom@archlinux.org>
   2 # Committer: dorphell <dorphell@archlinux.org>
   3
   4 pkgname=libtheora
   5 pkgver=1.1.1
   6 pkgrel=5
   7 pkgdesc="An open video codec developed by the Xiph.org"
   8 arch=('x86_64')
   9 url="https://www.theora.org/"
  10 license=('BSD')
  11 depends=('libogg')
  12 makedepends=('libvorbis')
  13 source=(https://downloads.xiph.org/releases/theora/libtheora-${pkgver}.tar.bz2
  14         libtheora-1.1.1-libpng16.patch)
  15 sha256sums=('b6ae1ee2fa3d42ac489287d3ec34c5885730b1296f0801ae577a35193d3affbc'
  16             'e4c9a8dc798c596ed32a2a720020ae27a0e72f5add1a47cb8fadebe0e7180d7e')
  17
  18 prepare() {
  19   cd ${pkgname}-${pkgver}
  20   patch -Np0 -i ../libtheora-1.1.1-libpng16.patch
  21 }
  22
  23 build() {
  24   cd ${pkgname}-${pkgver}
  25   ./configure --prefix=/usr --enable-shared --disable-static
  26   make
  27 }
  28
  29 package() {
  30   cd ${pkgname}-${pkgver}
  31   make DESTDIR="${pkgdir}" install
  32
  33   install -m755 -d "${pkgdir}/usr/share/licenses/${pkgname}"
  34   install -m644 LICENSE COPYING "${pkgdir}/usr/share/licenses/${pkgname}/"
  35 }