libxcrypt/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2
   3 pkgbase=libxcrypt
   4 pkgname=(libxcrypt libxcrypt-compat)
   5 pkgver=4.4.33
   6 pkgrel=1
   7 pkgdesc='Modern library for one-way hashing of passwords'
   8 arch=('x86_64')
   9 url='https://github.com/besser82/libxcrypt/'
  10 license=('GPL')
  11 depends=('glibc')
  12 provides=('libcrypt.so')
  13 install=libxcrypt.install
  14 validpgpkeys=('678CE3FEE430311596DB8C16F52E98007594C21D') # Björn 'besser82' Esser
  15 source=("${url}/releases/download/v${pkgver}/${pkgbase}-${pkgver}.tar.xz"{,.asc})
  16 sha256sums=('e87acf9c652c573a4713d5582159f98f305d56ed5f754ce64f57d4194d6b3a6f'
  17             'SKIP')
  18
  19 build() {
  20   mkdir build-libxcrypt build-libxcrypt-compat
  21
  22   cd "${srcdir}/build-libxcrypt/"
  23   "${srcdir}/${pkgbase}-${pkgver}"/configure \
  24     --prefix=/usr \
  25     --disable-static \
  26     --enable-hashes=strong,glibc \
  27     --enable-obsolete-api=no \
  28     --disable-failure-tokens
  29   make
  30
  31   cd "${srcdir}/build-libxcrypt-compat/"
  32   "${srcdir}/${pkgbase}-${pkgver}"/configure \
  33     --prefix=/usr \
  34     --disable-static \
  35     --enable-hashes=strong,glibc \
  36     --enable-obsolete-api=glibc \
  37     --disable-failure-tokens
  38   make
  39 }
  40
  41 check() {
  42   cd build-libxcrypt/
  43
  44   make check
  45 }
  46
  47 package_libxcrypt() {
  48   cd build-libxcrypt/
  49
  50   make DESTDIR="${pkgdir}" install
  51 }
  52
  53 package_libxcrypt-compat() {
  54   pkgdesc='Modern library for one-way hashing of passwords - legacy API functions'
  55   depends=('libxcrypt')
  56
  57   cd build-libxcrypt-compat/
  58
  59   make DESTDIR="${pkgdir}" install
  60
  61   rm -rf "${pkgdir}"/usr/{include,lib/{lib*.so,pkgconfig},share}
  62 }