lzo/trunk/PKGBUILD

   1 # Contributor: Low Kian Seong <fastmail_low@speedymail.org>
   2 # Maintainer: dorphell <dorphell@archlinux.org>
   3
   4 pkgname=lzo
   5 pkgver=2.10
   6 pkgrel=5
   7 pkgdesc="Portable lossless data compression library"
   8 arch=('x86_64')
   9 url="https://www.oberhumer.com/opensource/lzo"
  10 license=('GPL')
  11 depends=('glibc')
  12 provides=('liblzo2.so' 'libminilzo.so')
  13 source=(https://www.oberhumer.com/opensource/lzo/download/lzo-${pkgver}.tar.gz)
  14 sha256sums=('c0f892943208266f9b6543b3ae308fab6284c5c90e627931446fb49b4221a072')
  15
  16 build() {
  17   cd lzo-${pkgver}
  18   ./configure --prefix=/usr --enable-shared
  19   make
  20
  21   # build minilzo
  22   gcc $CPPFLAGS $CFLAGS -fpic -Iinclude/lzo -o minilzo/minilzo.o -c minilzo/minilzo.c
  23   gcc $LDFLAGS -shared -o libminilzo.so.0 -Wl,-soname,libminilzo.so.0 minilzo/minilzo.o
  24 }
  25
  26 check() {
  27   cd lzo-${pkgver}
  28   make test # Larger test
  29   make check
  30 }
  31
  32 package() {
  33   cd lzo-${pkgver}
  34   make DESTDIR="${pkgdir}" install
  35
  36   # install minilzo
  37   install -m 755 libminilzo.so.0 "${pkgdir}"/usr/lib
  38   install -p -m 644 minilzo/minilzo.h ${pkgdir}/usr/include/lzo
  39   cd "${pkgdir}"/usr/lib
  40   ln -s libminilzo.so.0 libminilzo.so
  41 }