media-player-info/repos/extra-any/PKGBUILD

   1 # Maintainer : Ionut Biru <ibiru@archlinux.org>
   2 # Contributor: Marti Raudsepp <marti@juffo.org>
   3
   4 pkgname=media-player-info
   5 pkgver=24
   6 pkgrel=2
   7 pkgdesc="Data files describing media player capabilities, for post-HAL systems"
   8 arch=('any')
   9 license=('BSD')
  10 url="https://www.freedesktop.org/wiki/Software/media-player-info/"
  11 depends=('systemd')
  12 makedepends=('python' git)
  13 _commit=337c758d95cc37f5a1b7a2a065e2e2cd8a75c4d8  # tags/24^0
  14 source=("git+https://anongit.freedesktop.org/git/media-player-info#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24   NOCONFIGURE=1 ./autogen.sh
  25 }
  26
  27 check() {
  28   cd $pkgname
  29   make check
  30 }
  31
  32 build() {
  33   cd $pkgname
  34
  35   ./configure --prefix=/usr \
  36       --with-udevdir=/usr/lib/udev
  37   LANG="en_US.UTF-8" make
  38 }
  39
  40 package() {
  41   cd "$pkgname"
  42   make DESTDIR="$pkgdir" install
  43
  44   install -d "$pkgdir/usr/share/licenses/$pkgname"
  45   install -m644 COPYING "$pkgdir/usr/share/licenses/$pkgname"
  46 }