nspr/repos/core-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Alexander Baldeck <alexander@archlinux.org>
   4
   5 pkgname=nspr
   6 pkgver=4.35
   7 pkgrel=1
   8 pkgdesc="Netscape Portable Runtime"
   9 url="https://developer.mozilla.org/en-US/docs/Mozilla/Projects/NSPR"
  10 arch=(x86_64)
  11 license=(MPL GPL)
  12 depends=(glibc sh)
  13 makedepends=(zip mercurial)
  14 options=(debug)
  15 _revision=b563bfc16c887c48b038b7b441fcc4e40a126d3b
  16 source=("hg+https://hg.mozilla.org/projects/nspr#revision=$_revision")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd nspr
  21   hg id -t -r. | sed 's/^NSPR_//;s/_RTM$//;s/_/./g'
  22 }
  23
  24 prepare() {
  25   cd nspr
  26 }
  27
  28 build() {
  29   cd nspr
  30   ./configure \
  31       --prefix=/usr \
  32       --libdir=/usr/lib \
  33       --includedir=/usr/include/nspr \
  34       --enable-optimize \
  35       --disable-debug \
  36       --enable-64bit
  37   make ${SOURCE_DATE_EPOCH:+
  38     SH_NOW="${SOURCE_DATE_EPOCH}000000"
  39     SH_DATE="$(date --utc --date="@$SOURCE_DATE_EPOCH" '+%Y-%m-%d %T')"
  40   }
  41 }
  42
  43 package() {
  44   cd nspr
  45   make DESTDIR="$pkgdir" install
  46   ln -s nspr.pc "$pkgdir/usr/lib/pkgconfig/mozilla-nspr.pc"
  47
  48   rm -r "$pkgdir"/usr/include/nspr/md
  49   rm "$pkgdir"/usr/bin/{compile-et.pl,prerr.properties}
  50 }
  51
  52 # vim:set sw=2 et: