valadoc/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
   2
   3 pkgname=valadoc
   4 pkgver=0.36.2
   5 pkgrel=1
   6 epoch=1
   7 pkgdesc="A documentation tool for vala"
   8 arch=(x86_64)
   9 url="https://git.gnome.org/browse/valadoc"
  10 license=(GPL2)
  11 depends=(vala gtk-doc graphviz libgee ttf-dejavu)
  12 makedepends=(git)
  13 _commit=b2172f45ee815d4575fd3c6f75cafe035cc26224  # tags/0.36.2^0
  14 source=("git+https://git.gnome.org/browse/valadoc#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24   NOCONFIGURE=1 ./autogen.sh
  25 }
  26
  27 build() {
  28   cd $pkgname
  29   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var
  30   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  31   make
  32 }
  33
  34 package() {
  35   cd $pkgname
  36   make DESTDIR="$pkgdir" install
  37 }