vino/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=vino
   5 pkgver=3.22.0+74+g7a95e10
   6 pkgrel=1
   7 pkgdesc="A VNC server for the GNOME desktop"
   8 url="https://wiki.gnome.org/Projects/Vino"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(libnotify libxtst libsm telepathy-glib gtk3 libsecret avahi gnutls)
  12 makedepends=(intltool networkmanager gnome-common git)
  13 groups=(gnome)
  14 _commit=7a95e105ec0a68dc0057b12ab4d15d628511a559  # master
  15 source=("git+https://gitlab.gnome.org/GNOME/vino.git#commit=$_commit")
  16 sha256sums=('SKIP')
  17
  18 pkgver() {
  19   cd $pkgname
  20   git describe --tags | sed 's/-/+/g'
  21 }
  22
  23 prepare() {
  24   cd $pkgname
  25   NOCONFIGURE=1 ./autogen.sh
  26 }
  27
  28 build() {
  29   cd $pkgname
  30
  31   ./configure --prefix=/usr --sysconfdir=/etc \
  32       --libexecdir=/usr/lib/vino \
  33       --localstatedir=/var \
  34       --disable-http-server --with-secret
  35
  36   # https://bugzilla.gnome.org/show_bug.cgi?id=655517
  37   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  38
  39   make
  40 }
  41
  42 package() {
  43   cd $pkgname
  44   make DESTDIR="$pkgdir" install
  45 }