egl-wayland/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=egl-wayland
   4 pkgver=1.1.9+r3+g582b2d3
   5 pkgrel=1
   6 epoch=2
   7 pkgdesc="EGLStream-based Wayland external platform"
   8 arch=(x86_64)
   9 url=https://github.com/NVIDIA/egl-wayland
  10 license=(MIT)
  11 depends=(wayland eglexternalplatform)
  12 makedepends=(meson git wayland-protocols 'libglvnd>=1.3.4')
  13 provides=(libnvidia-egl-wayland.so)
  14 _commit=582b2d345abaa0e313cf16c902e602084ea59551  # master
  15 source=("git+$url#commit=$_commit"
  16         10_nvidia_wayland.json)
  17 sha256sums=('SKIP'
  18             '5cccf1905a266e8e34d5ad4aad4be85390e60b1a0850a29dd9d64adc641de412')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27 }
  28
  29 build() {
  30   arch-meson $pkgname build
  31   meson compile -C build
  32 }
  33
  34 check() {
  35   meson test -C build --print-errorlogs
  36 }
  37
  38 package() {
  39   meson install -C build --destdir "$pkgdir"
  40   install -Dt "$pkgdir/usr/share/egl/egl_external_platform.d" -m644 10_nvidia_wayland.json
  41   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 $pkgname/COPYING
  42 }
  43
  44 # vim:set sw=2 et: