libsecret/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Maintainer: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=libsecret
   5 pkgver=0.20.4
   6 pkgrel=1
   7 pkgdesc="Library for storing and retrieving passwords and other secrets"
   8 url="https://wiki.gnome.org/Projects/Libsecret"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(glib2 libgcrypt)
  12 checkdepends=(python-dbus dbus-glib python-gobject gjs)
  13 makedepends=(docbook-xsl gobject-introspection vala git gtk-doc meson valgrind)
  14 optdepends=('org.freedesktop.secrets: secret storage backend')
  15 provides=(libsecret-1.so)
  16 _commit=3fe635e64efd4b8dbc9ec3548b0bc8034c7665c4  # tags/0.20.4^0
  17 source=("git+https://gitlab.gnome.org/GNOME/libsecret.git#commit=$_commit"
  18         fix-test.diff)
  19 sha256sums=('SKIP'
  20             '760e40ffcd3383149d62f803a900b3af1a838fb084a8403e45d0764696dd2ffe')
  21
  22 pkgver() {
  23   cd $pkgname
  24   git describe --tags | sed 's/-/+/g'
  25 }
  26
  27 prepare() {
  28   cd $pkgname
  29
  30   # Fix compiliation of test-vala-unstable
  31   # https://gitlab.gnome.org/GNOME/libsecret/-/issues/54
  32   git apply -3 ../fix-test.diff
  33 }
  34
  35 build() {
  36   arch-meson $pkgname build
  37   meson compile -C build
  38 }
  39
  40 check() {
  41   dbus-run-session meson test -C build --print-errorlogs
  42 }
  43
  44 package() {
  45   DESTDIR="$pkgdir" meson install -C build
  46 }
  47
  48 # vim:set sw=2 et: