mypaint-brushes1/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: vimacs <https://vimacs.lcpu.club>
   3
   4 pkgname=mypaint-brushes1
   5 pkgver=1.3.1
   6 pkgrel=1
   7 pkgdesc='Brushes used by MyPaint and other software using libmypaint (v1.x)'
   8 url='https://github.com/mypaint/mypaint-brushes'
   9 arch=('any')
  10 license=('custom:CC0')
  11 depends=('libmypaint<2')
  12 source=(https://github.com/mypaint/mypaint-brushes/archive/v${pkgver}/${pkgname/1/}-${pkgver}.tar.gz)
  13 sha512sums=('3e65619ae9a042cd6314396a826a2b63a72066e761244dc8763910555715b1dff6aa4395b5322510b114d61bb486f909fe505a564c89a2a5e1e5087ed298d08b')
  14 b2sums=('d2eb967fe0bd303c16ad15a9d5ed1e41d25cbb4c42fa534de4cedfabe408655300fc3f6a087c20586492fd4e87398597a15d5bfd31c2dd86ae44b1e1f329d0e0')
  15
  16 prepare() {
  17   cd ${pkgname/1/}-${pkgver}
  18   autoreconf -fiv
  19 }
  20
  21 build() {
  22   cd ${pkgname/1/}-${pkgver}
  23   ./configure --prefix=/usr
  24   make
  25 }
  26
  27 package() {
  28   cd ${pkgname/1/}-${pkgver}
  29   make DESTDIR="${pkgdir}" install
  30   install -Dm 644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
  31 }
  32
  33 # vim: ts=2 sw=2 et: