gnome-photos/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-photos
   4 pkgver=42.0
   5 pkgrel=1
   6 epoch=1
   7 pkgdesc="Access, organize, and share your photos on GNOME"
   8 arch=(x86_64)
   9 url="https://wiki.gnome.org/Apps/Photos"
  10 license=(GPL)
  11 depends=(exempi gtk3 libexif librsvg babl gegl gsettings-desktop-schemas
  12          grilo-plugins lcms2 tracker3-miners geocode-glib grilo gfbgraph libgdata
  13          libgexiv2 libraw gnome-online-accounts dleyna-server dleyna-renderer
  14          libdazzle libhandy)
  15 makedepends=(python yelp-tools git meson docbook-xsl)
  16 groups=(gnome)
  17 options=(debug)
  18 _commit=263d82c16b18db0f59c123e34f317a6926debdd8  # tags/42.0^0
  19 source=("git+https://gitlab.gnome.org/GNOME/gnome-photos.git#commit=$_commit"
  20         "git+https://gitlab.gnome.org/GNOME/libgd.git")
  21 sha256sums=('SKIP'
  22             'SKIP')
  23
  24 pkgver() {
  25   cd $pkgname
  26   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  27 }
  28
  29 prepare() {
  30   cd $pkgname
  31
  32   git submodule init
  33   git submodule set-url subprojects/libgd "$srcdir/libgd"
  34   git submodule update
  35 }
  36
  37 build() {
  38   arch-meson $pkgname build -D manuals=true
  39   meson compile -C build
  40 }
  41
  42 package() {
  43   meson install -C build --destdir "$pkgdir"
  44 }