libtool/trunk/PKGBUILD

   1 # Maintainer: Giancarlo Razzolini <grazzolini@archlinux.org>
   2 # Maintainer: Frederik Schwan <freswa at archlinux dot org>
   3 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   4 # Contributor: Allan McRae <allan@archlinux.org>
   5 # Contributor: judd <jvinet@zeroflux.org>
   6
   7 # NOTE: requires rebuilt with each new gcc version
   8
   9 pkgname=libtool
  10 pkgver=2.4.7
  11 pkgrel=5
  12 _gccver=12.2.0
  13 pkgdesc='A generic library support script'
  14 arch=(x86_64)
  15 url='https://www.gnu.org/software/libtool'
  16 license=(GPL)
  17 groups=(base-devel)
  18 depends=(sh tar glibc)
  19 makedepends=("gcc>=$_gccver" git help2man)
  20 checkdepends=(gcc-fortran)
  21 provides=("libltdl=$pkgver" "libtool-multilib=$pkgver")
  22 conflicts=(libltdl libtool-multilib)
  23 replaces=(libltdl libtool-multilib)
  24 options=(debug)
  25 _commit=6d7ce133ce54898cf28abd89d167cccfbc3c9b2b
  26 source=(git+https://git.savannah.gnu.org/git/libtool.git#commit=$_commit
  27         git+https://git.savannah.gnu.org/git/gnulib.git
  28         gnulib-bootstrap::git+https://github.com/gnulib-modules/bootstrap.git
  29         no_hostname.patch
  30         disable-lto-link-order2.patch)
  31 sha256sums=('SKIP'
  32             'SKIP'
  33             'SKIP'
  34             '693aabb24a6e7ce21fe0b5d14394e19edcb8476663b5afa4463f9fa0df24d946'
  35             'b6dce6681f223b18a90614edbcdeb00f228abd1216e22c4bd07285321cd2ceb7')
  36
  37 pkgver() {
  38   cd libtool
  39   git describe --tags | sed 's/-/+/g;s/^v//'
  40 }
  41
  42 prepare() {
  43   cd libtool
  44
  45   patch -Np1 -i ${srcdir}/no_hostname.patch
  46
  47   # test 67 is broken with lto
  48   # this patch removes the -flto flag for this very test
  49   # adapt when -ffat-lto-objects is enabled by Arch
  50   patch -Np1 -i ${srcdir}/disable-lto-link-order2.patch
  51
  52   git submodule init
  53   git config --local submodule.gnulib.url "$srcdir/gnulib"
  54   git config --local submodule.gl-mod/bootstrap.url "$srcdir/gnulib-bootstrap"
  55   git submodule update
  56
  57   ./bootstrap
  58 }
  59
  60 build() {
  61   cd libtool
  62   ./configure --prefix=/usr lt_cv_sys_lib_dlsearch_path_spec="/usr/lib /usr/lib32"
  63   make
  64 }
  65
  66 check() {
  67   cd libtool
  68   make check gl_public_submodule_commit=
  69 }
  70
  71 package() {
  72   cd libtool
  73   make DESTDIR="$pkgdir" install
  74 }