meld/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Gaetan Bisson <bisson@archlinux.org>
   3 # Contributor: Daniel J Griffiths <ghost1227@archlinux.us>
   4 # Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
   5
   6 pkgname=meld
   7 pkgver=3.22.0
   8 pkgrel=1
   9 pkgdesc="Compare files, directories and working copies"
  10 url="https://meldmerge.org/"
  11 license=(GPL)
  12 arch=(any)
  13 depends=(python-gobject python-cairo gtksourceview4 gsettings-desktop-schemas
  14          dconf)
  15 makedepends=(meson yelp-tools git)
  16 checkdepends=(appstream-glib)
  17 _commit=322f05876e841d1fa7a162d4c5a4e15226823b7c  # tags/3.22.0^0
  18 source=("git+https://gitlab.gnome.org/GNOME/meld.git#commit=$_commit")
  19 sha256sums=('SKIP')
  20
  21 pkgver() {
  22   cd meld
  23   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  24 }
  25
  26 prepare() {
  27   cd meld
  28 }
  29
  30 build() {
  31   arch-meson meld build
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 package() {
  40   meson install -C build --destdir "$pkgdir"
  41   python -m compileall -d /usr/lib "$pkgdir/usr/lib"
  42   python -O -m compileall -d /usr/lib "$pkgdir/usr/lib"
  43 }