networkmanager-vpnc/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgname=networkmanager-vpnc
   5 pkgver=1.2.8
   6 pkgrel=2
   7 pkgdesc="NetworkManager VPN plugin for VPNC"
   8 url="https://wiki.gnome.org/Projects/NetworkManager"
   9 arch=(x86_64)
  10 license=(GPL)
  11 depends=(libnm libsecret vpnc)
  12 makedepends=(libnma libnma-gtk4 intltool python git)
  13 optdepends=('libnma: GUI support (GTK 3)'
  14             'libnma-gtk4: GUI support (GTK 4)')
  15 options=(debug)
  16 _commit=75f664ff13ff1de9bf305894ccd94b30867bd06a  # tags/1.2.8^0
  17 source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-vpnc.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd NetworkManager-vpnc
  22   git describe --tags | sed 's/-dev/dev/;s/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd NetworkManager-vpnc
  27   intltoolize --automake --copy
  28   autoreconf -fvi
  29 }
  30
  31 build() {
  32   cd NetworkManager-vpnc
  33   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  34     --libexecdir=/usr/lib --disable-static --with-gtk4
  35   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  36   make
  37 }
  38
  39 package() {
  40   cd NetworkManager-vpnc
  41   make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
  42 }
  43
  44 # vim:set sw=2 et: