tracker/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Sergej Pupykin <pupykin.s+arch@gmail.com>
   3 # Contributor: Alexander Fehr <pizzapunk gmail com>
   4
   5 pkgname=tracker
   6 pkgver=2.3.6+r7+gb27396252
   7 pkgrel=1
   8 epoch=1
   9 pkgdesc="Desktop-neutral user information store, search tool and indexer"
  10 url="https://wiki.gnome.org/Projects/Tracker"
  11 arch=(x86_64)
  12 license=(GPL)
  13 depends=(sqlite icu glib2 libffi util-linux libstemmer libseccomp json-glib
  14          libsoup upower libnm)
  15 makedepends=(gobject-introspection vala git bash-completion meson)
  16 checkdepends=(python-gobject python-dbus)
  17 provides=(libtracker-{control,miner,sparql}-2.0.so)
  18 options=(debug)
  19 _commit=b2739625209c564192b339814264084046e1cf17  # tracker-2.3
  20 source=("git+https://gitlab.gnome.org/GNOME/tracker.git#commit=$_commit"
  21         0001-libtracker-data-Workaround-SQLite-3.35.x-bug.patch)
  22 sha256sums=('SKIP'
  23             '2dc030fb047e99420bd330d5eee1fd70bd26a7ee0adf31f90c724bd0732ed67d')
  24
  25 pkgver() {
  26   cd tracker
  27   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  28 }
  29
  30 prepare() {
  31   cd tracker
  32
  33   # https://gitlab.gnome.org/GNOME/tracker/-/merge_requests/382
  34   git apply -3 ../0001-libtracker-data-Workaround-SQLite-3.35.x-bug.patch
  35 }
  36
  37 build() {
  38   arch-meson tracker build
  39   meson compile -C build
  40 }
  41
  42 check() {
  43   dbus-run-session meson test -C build --print-errorlogs -t 3
  44 }
  45
  46 package() {
  47   meson install -C build --destdir "$pkgdir"
  48 }
  49
  50 # vim:set sw=2 et: