gnome-autoar/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=gnome-autoar
   5 pkgver=0.4.3
   6 pkgrel=2
   7 pkgdesc="Automatic archives creating and extracting library"
   8 url="https://wiki.gnome.org/TingweiLan/GSoC2013Final"
   9 arch=(x86_64)
  10 license=(LGPL)
  11 depends=(glib2 libarchive gtk3)
  12 makedepends=(git gobject-introspection gtk-doc vala meson)
  13 provides=(libgnome-autoar{,-gtk}-${pkgver%%.*}.so)
  14 options=(debug)
  15 _commit=5739d99e286922dda48d4c0ebe51849c04561303  # tags/0.4.3^0
  16 source=("git+https://gitlab.gnome.org/GNOME/gnome-autoar.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26 }
  27
  28 build() {
  29   arch-meson $pkgname build \
  30     -D gtk_doc=true \
  31     -D tests=true \
  32     -D vapi=true
  33   meson compile -C build
  34 }
  35
  36 check() {
  37   meson test -C build --print-errorlogs
  38 }
  39
  40 package() {
  41   meson install -C build --destdir "$pkgdir"
  42 }