gnome-settings-daemon/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2
   3 pkgname=gnome-settings-daemon
   4 pkgver=42.2
   5 pkgrel=1
   6 pkgdesc="GNOME Settings Daemon"
   7 url="https://gitlab.gnome.org/GNOME/gnome-settings-daemon"
   8 arch=(x86_64)
   9 license=(GPL)
  10 depends=(dconf gnome-desktop gsettings-desktop-schemas libcanberra-pulse
  11          libnotify systemd libwacom pulseaudio pulseaudio-alsa upower librsvg
  12          libgweather-4 geocode-glib geoclue nss libgudev gtk3 libnm gcr)
  13 makedepends=(libxslt docbook-xsl python git meson usbguard)
  14 checkdepends=(python-gobject python-dbusmock)
  15 optdepends=('usbguard: USB protection support')
  16 groups=(gnome)
  17 backup=(etc/xdg/Xwayland-session.d/00-xrdb)
  18 options=(debug)
  19 _commit=4bdf8b5ae38a382be4126bbc0ce8d87bac46177e  # tags/42.2^0
  20 source=("git+https://gitlab.gnome.org/GNOME/gnome-settings-daemon.git#commit=$_commit"
  21         "git+https://gitlab.gnome.org/GNOME/libgnome-volume-control.git")
  22 sha256sums=('SKIP'
  23             'SKIP')
  24
  25 pkgver() {
  26   cd $pkgname
  27   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  28 }
  29
  30 prepare() {
  31   cd $pkgname
  32
  33   git submodule init
  34   git submodule set-url subprojects/gvc "$srcdir/libgnome-volume-control"
  35   git submodule update
  36 }
  37
  38 build() {
  39   arch-meson $pkgname build
  40   meson compile -C build
  41 }
  42
  43 check() {
  44   meson test -C build --print-errorlogs
  45 }
  46
  47 package() {
  48   meson install -C build --destdir "$pkgdir"
  49 }