lz4/trunk/PKGBUILD

   1 # Maintainer: Sébastien Luttringer
   2
   3 pkgname=lz4
   4 epoch=1
   5 pkgver=1.9.4
   6 pkgrel=1
   7 pkgdesc='Extremely fast compression algorithm'
   8 arch=('x86_64')
   9 url='https://lz4.github.io/lz4/'
  10 license=('GPL2')
  11 makedepends=('git')
  12 checkdepends=('diffutils')
  13 depends=('glibc')
  14 source=("git+https://github.com/lz4/lz4.git#tag=v$pkgver")
  15 sha256sums=('SKIP')
  16
  17 prepare() {
  18   cd $pkgname
  19   # apply patch from the source array (should be a pacman feature)
  20   local src
  21   for src in "${source[@]}"; do
  22     src="${src%%::*}"
  23     src="${src##*/}"
  24     [[ $src = *.patch ]] || continue
  25     msg2 "Applying patch $src..."
  26     patch -Np1 < "../$src"
  27   done
  28 }
  29
  30 build() {
  31   # do not use the main makefile, it calls sub make with -e
  32   # exported CLFAGS by makepkg break the version. see FS#50071
  33   cd $pkgname
  34   make -C lib PREFIX=/usr
  35   make -C programs PREFIX=/usr lz4 lz4c
  36 }
  37
  38 check() {
  39   rm -f passwd.lz4
  40   $pkgname/programs/lz4 /etc/passwd passwd.lz4
  41   $pkgname/programs/lz4 -d passwd.lz4 passwd
  42   diff -q /etc/passwd passwd
  43   rm passwd
  44 }
  45
  46 package() {
  47   cd $pkgname
  48   make install PREFIX=/usr DESTDIR="$pkgdir"
  49 }
  50
  51 # vim:set ts=2 sw=2 et: