rygel/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Balló György <ballogyor+arch at gmail dot com>
   3
   4 pkgname=rygel
   5 pkgver=0.40.4
   6 pkgrel=1
   7 epoch=1
   8 pkgdesc="UPnP AV MediaServer and MediaRenderer"
   9 url="https://wiki.gnome.org/Projects/Rygel"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(gupnp gupnp-av gupnp-dlna libgee gtk3 libunistring tracker3
  13          libmediaart gst-editing-services)
  14 makedepends=(vala gobject-introspection git meson)
  15 optdepends=('gst-plugins-base: Extra media codecs'
  16             'gst-plugins-good: Extra media codecs'
  17             'gst-plugins-bad: Extra media codecs'
  18             'gst-plugins-ugly: Extra media codecs'
  19             'gst-libav: Extra media codecs'
  20             'tracker3-miners: Share indexed media files'
  21             'tumbler: Thumbnailing service')
  22 backup=(etc/rygel.conf)
  23 groups=(gnome)
  24 options=(debug)
  25 _commit=d7ffde7f9ab6428782efce59d9755a30e8bfda8e  # tags/rygel-0.40.4^0
  26 source=("git+https://gitlab.gnome.org/GNOME/rygel.git#commit=$_commit")
  27 sha256sums=('SKIP')
  28
  29 pkgver() {
  30   cd rygel
  31   git describe --tags | sed 's/^rygel-//;s/[^-]*-g/r&/;s/-/+/g'
  32 }
  33
  34 prepare() {
  35   cd rygel
  36   git cherry-pick -n d0410cccf6af55e16d3ba9400ad5e9f703313739
  37 }
  38
  39 build() {
  40   arch-meson rygel build
  41   meson compile -C build
  42 }
  43
  44 check() {
  45   meson test -C build --print-errorlogs
  46 }
  47
  48 package() {
  49   meson install -C build --destdir "$pkgdir"
  50 }
  51
  52 # vim:set sw=2 et: