sound-juicer/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Ben <contrasutra@myrealbox.com>
   4
   5 pkgname=sound-juicer
   6 pkgver=3.38.0+r27+g9f97ca1f
   7 pkgrel=1
   8 pkgdesc="A lean and friendly audio CD extractor for GNOME"
   9 url="https://wiki.gnome.org/Apps/SoundJuicer"
  10 arch=(x86_64)
  11 license=(GPL)
  12 depends=(libmusicbrainz5 libdiscid gtk3 gst-plugins-base gst-plugins-good
  13          brasero iso-codes libcanberra)
  14 makedepends=(itstool appstream-glib git meson)
  15 _commit=9f97ca1faca396099f52264a9729aa355f8d122e  # master
  16 source=("git+https://gitlab.gnome.org/GNOME/sound-juicer.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd $pkgname
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd $pkgname
  26 }
  27
  28 build() {
  29   arch-meson $pkgname build
  30   meson compile -C build
  31 }
  32
  33 check() {
  34   meson test -C build --print-errorlogs
  35 }
  36
  37 package() {
  38   meson install -C build --destdir "$pkgdir"
  39 }