vte3/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Ionut Biru <ibiru@archlinux.org>
   3
   4 pkgbase=vte3
   5 pkgname=(vte3 vte-common)
   6 pkgver=0.68.0
   7 pkgrel=2
   8 pkgdesc="Virtual Terminal Emulator widget"
   9 url="https://wiki.gnome.org/Apps/Terminal/VTE"
  10 arch=(x86_64)
  11 license=(LGPL)
  12 depends=(gtk3 pcre2 gnutls fribidi systemd)
  13 makedepends=(gobject-introspection vala git gtk-doc gperf meson)
  14 options=(debug)
  15 _commit=0f438924f9f8a858b1b82434c876e31c2de180d4  # tags/0.68.0^0
  16 source=("git+https://gitlab.gnome.org/GNOME/vte.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd vte
  21   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd vte
  26 }
  27
  28 build() {
  29   arch-meson vte build \
  30     -D b_lto=false \
  31     -D docs=true
  32   meson compile -C build
  33 }
  34
  35 check() {
  36   meson test -C build --print-errorlogs
  37 }
  38
  39 _pick() {
  40   local p="$1" f d; shift
  41   for f; do
  42     d="$srcdir/$p/${f#$pkgdir/}"
  43     mkdir -p "$(dirname "$d")"
  44     mv "$f" "$d"
  45     rmdir -p --ignore-fail-on-non-empty "$(dirname "$f")"
  46   done
  47 }
  48
  49 package_vte3() {
  50   depends+=(vte-common)
  51   provides+=(libvte-2.91.so)
  52
  53   meson install -C build --destdir "$pkgdir"
  54
  55   _pick vte-common "$pkgdir"/etc/profile.d
  56   _pick vte-common "$pkgdir"/usr/lib/{systemd,vte-urlencode-cwd}
  57 }
  58
  59 package_vte-common() {
  60   pkgdesc="Files shared by VTE libraries"
  61   depends=(sh)
  62   mv vte-common/* "$pkgdir"
  63 }
  64
  65 # vim:set sw=2 et: