python-ordered-set/repos/extra-any/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Tobias Roettger <toroettg@gmail.com>
   3
   4 pkgname=python-ordered-set
   5 pkgver=4.1.0
   6 pkgrel=4
   7 pkgdesc='A MutableSet that remembers its order, so that every entry has an index'
   8 arch=('any')
   9 url="https://github.com/rspeer/ordered-set"
  10 license=('MIT')
  11 depends=('python')
  12 makedepends=('python-build' 'python-flit-core' 'python-installer')
  13 checkdepends=('python-pytest')
  14 source=("https://pypi.io/packages/source/o/ordered-set/ordered-set-$pkgver.tar.gz")
  15 sha512sums=('f12d19f7d9cf0ebcc414d97798f0959ff69a77146839cc6a9067c864f9e0be795795c4d648f736fd7448ddf89666ce37f23e7380d1c9b1678a4787961e4e1e79')
  16
  17 build() {
  18   cd ordered-set-$pkgver
  19   python -m build --wheel --no-isolation
  20 }
  21
  22 check() {
  23   cd ordered-set-$pkgver
  24   pytest
  25 }
  26
  27 package() {
  28   cd ordered-set-$pkgver
  29   python -m installer --destdir="$pkgdir/" dist/*.whl
  30   install -Dm644 MIT-LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  31 }
  32
  33 # vim:set ts=2 sw=2 et: