talloc/trunk/PKGBUILD

   1 # Maintainer:
   2 # Contributor: Tobias Powalowski <tpowa@archlinux.org>
   3
   4 pkgname=talloc
   5 pkgver=2.4.0
   6 pkgrel=3
   7 pkgdesc="Hierarchical pool based memory allocator with destructors"
   8 arch=('x86_64')
   9 license=('GPL3')
  10 url="https://talloc.samba.org/"
  11 depends=('glibc' 'libxcrypt')
  12 makedepends=('python' 'docbook-xsl')
  13 optdepends=('python: for python bindings')
  14 source=(https://www.samba.org/ftp/talloc/talloc-$pkgver.tar.{gz,asc})
  15 sha512sums=('810d92a614d0b9e0ac6fe403c1643c4dda435f79c4627d3c3be228f94b4b2ee8e528efbbed07f7d1a16043d6e55bdf4f10826f31fb8ca1c649c4126ea09a3aff'
  16             'SKIP')
  17 validpgpkeys=(9147A339719518EE9011BCB54793916113084025) # samba-bugs@samba.org
  18
  19 build() {
  20    cd "${srcdir}/${pkgname}-${pkgver}"
  21    ./configure --prefix=/usr \
  22      --sysconfdir=/etc/samba \
  23      --localstatedir=/var \
  24      --bundled-libraries=NONE \
  25      --builtin-libraries=replace \
  26      --enable-talloc-compat1
  27    make
  28 }
  29
  30 check() {
  31   cd "${srcdir}/${pkgname}-${pkgver}"
  32   make check
  33 }
  34
  35 package() {
  36    cd "${srcdir}/${pkgname}-${pkgver}"
  37    make DESTDIR="${pkgdir}" install
  38 }