expat/repos/core-x86_64/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2 # Contributor: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   3 # Contributor: Allan McRae <allan@archlinux.org>
   4 # Contributor: Judd Vinet <jvinet@zeroflux.org>
   5
   6 pkgname=expat
   7 pkgver=2.4.1
   8 pkgrel=1
   9 pkgdesc='An XML parser library'
  10 arch=('x86_64')
  11 url="https://libexpat.github.io/"
  12 license=('MIT')
  13 depends=('glibc')
  14 makedepends=('cmake')
  15 provides=('libexpat.so')
  16 source=("https://github.com/libexpat/libexpat/releases/download/R_${pkgver//./_}/${pkgname}-${pkgver}.tar.bz2"{,.asc})
  17 sha512sums=('b24e19c3f91e0f3d1ad3b08a810b8874e272ddfc6d4fd8f79c14c13eddf410648343b9f69fba2ce165be46c143cecf8d66cf446b4930da42f92def555ecd3408'
  18             'SKIP')
  19 b2sums=('47a39b63023cc1a4bdb56a5b2e6a51d9dfdeb69b8d4138e9f822a48ab07b01ceff00dcadbce688a4d069961e99746f692f616c5a62d69cec2bd5f74c6066c317'
  20         'SKIP')
  21 validpgpkeys=(3176EF7DB2367F1FCA4F306B1F9B0E909AF37285) # Sebastian Pipping
  22
  23 build() {
  24   cd "$pkgname-$pkgver"
  25   cmake -DCMAKE_INSTALL_PREFIX=/usr \
  26         -DCMAKE_BUILD_TYPE='None' \
  27         -W no-dev \
  28         -B build \
  29         -S .
  30   make VERBOSE=1 -C build
  31 }
  32
  33 check() {
  34   cd "$pkgname-$pkgver"
  35   make VERBOSE=1 -C build test
  36 }
  37
  38 package() {
  39   cd "$pkgname-$pkgver"
  40   make VERBOSE=1 DESTDIR="$pkgdir" -C build install
  41   install -vDm 644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname/"
  42   install -vDm 644 {AUTHORS,Changes,README.md} \
  43     -t "${pkgdir}/usr/share/doc/${pkgname}/"
  44 }