genius/trunk/PKGBUILD

   1 # Maintainer: Jan de Groot <jgc@archlinux.org>
   2 # Contributor: Arjan Timmerman <arjan@soulfly.nl>
   3
   4 pkgname=genius
   5 pkgver=1.0.27
   6 pkgrel=1
   7 pkgdesc="Advanced calculator including a mathematical programming language"
   8 arch=('x86_64')
   9 license=('GPL')
  10 url="https://www.jirka.org/genius.html"
  11 depends=('mpfr' 'glib2' 'hicolor-icon-theme' 'gtk3' 'amtk' 'vte3' 'gtksourceview4')
  12 makedepends=('intltool' 'gtk-update-icon-cache' 'python')
  13 options=('!makeflags')
  14 source=(https://download.gnome.org/sources/genius/1.0/${pkgname}-${pkgver}.tar.xz)
  15 sha256sums=('0243b7c36b5f9e930c62778acd52deb188deeca704a5e195337018435d9e7bb5')
  16
  17 build() {
  18   cd $pkgname-$pkgver
  19   autoreconf -fi
  20   ./configure --prefix=/usr --sysconfdir=/etc \
  21       --libexecdir=/usr/lib/genius \
  22       --localstatedir=/var --disable-static \
  23       --disable-update-mimedb
  24   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  25   make
  26 }
  27
  28 package() {
  29   cd $pkgname-$pkgver
  30   make DESTDIR="${pkgdir}" install
  31 }