libepoxy/trunk/PKGBUILD

   1 # Maintainer: Laurent Carlier <lordheavym@gmail.com>
   2
   3 pkgname=libepoxy
   4 pkgver=1.5.9
   5 pkgrel=1
   6 pkgdesc="Library handling OpenGL function pointer management"
   7 url="https://github.com/anholt/libepoxy"
   8 arch=(x86_64)
   9 license=(MIT)
  10 depends=(glibc)
  11 makedepends=(python mesa-libgl git meson doxygen graphviz)
  12 checkdepends=(xorg-server-xvfb)
  13 _commit=ecfa8e0f083084181d36966fa084aca9a6c97d53  # tags/1.5.9^0
  14 source=("git+https://github.com/anholt/libepoxy#commit=$_commit")
  15 sha256sums=('SKIP')
  16
  17 pkgver() {
  18   cd $pkgname
  19   git describe --tags | sed 's/-/+/g'
  20 }
  21
  22 prepare() {
  23   cd $pkgname
  24 }
  25
  26 build() {
  27   arch-meson $pkgname build -D docs=true
  28   meson compile -C build
  29 }
  30
  31 check() {
  32   xvfb-run -s '-nolisten local' \
  33     meson test -C build --print-errorlogs
  34 }
  35
  36 package() {
  37   meson install -C build --destdir "$pkgdir"
  38   install -Dm644 $pkgname/COPYING "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  39 }
  40
  41 # vim:set sw=2 et: