xfsprogs/trunk/PKGBUILD

   1 # Maintainer : Tobias Powalowski <tpowa@archlinux.org>
   2 pkgname=xfsprogs
   3 pkgver=5.14.2
   4 pkgrel=1
   5 pkgdesc="XFS filesystem utilities"
   6 arch=('x86_64')
   7 license=('LGPL')
   8 url="https://xfs.org"
   9 depends=('sh' 'util-linux-libs' 'icu' 'device-mapper' 'libinih' 'liburcu')
  10 optdepends=('python: for xfs_scrub_all script'
  11             'smtp-forwarder: for xfs_scrub_fail script')
  12 makedepends=('git')
  13 options=('!makeflags')
  14 source=("git+https://git.kernel.org/pub/scm/fs/xfs/xfsprogs-dev.git#tag=v${pkgver}")
  15 md5sums=('SKIP')
  16
  17 build() {
  18   cd ${pkgname}-dev
  19   make configure
  20   export OPTIMIZER="-march=${CARCH/_/-} -O1"
  21   export DEBUG=-DNDEBUG
  22   ./configure --prefix=/usr --sbindir=/usr/bin --with-systemd-unit-dir=/usr/lib/systemd/system
  23   make
  24 }
  25
  26 package() {
  27   cd ${pkgname}-dev
  28   make DIST_ROOT="${pkgdir}" PKG_ROOT_SBIN_DIR="/usr/bin" install install-dev
  29   chown -R root "$pkgdir"
  30   chgrp -R root "$pkgdir"
  31   # add hack as we cannot set rootlibdir
  32   mv "${pkgdir}"/lib/libhandle.so* "${pkgdir}/usr/lib/"
  33   rm -rf "${pkgdir}/lib"
  34 }