accerciser/trunk/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Jan de Groot <jgc@archlinux.org>
   3 # Contributor: Steve Holmes <steve.holmes88@gmail.com>
   4 # Contributor: Giulio Bai <giulio@hewle.com>
   5
   6 pkgname=accerciser
   7 pkgver=3.40.0
   8 pkgrel=2
   9 pkgdesc="Interactive Python accessibility explorer for the GNOME desktop"
  10 arch=(any)
  11 url="https://wiki.gnome.org/Apps/Accerciser"
  12 license=(BSD)
  13 depends=(python gtk3 python-atspi ipython libwnck3 python-cairo python-xlib)
  14 makedepends=(appstream-glib yelp-tools git)
  15 groups=(gnome-extra)
  16 _commit=3c7c127830cd8dc0bc69a8f88448d25674df1d80  # tags/3.40.0^0
  17 source=("git+https://gitlab.gnome.org/GNOME/accerciser.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  23 }
  24
  25 prepare() {
  26   cd $pkgname
  27   NOCONFIGURE=1 ./autogen.sh
  28 }
  29
  30 build() {
  31   cd $pkgname
  32   ./configure --prefix=/usr --sysconfdir=/etc --disable-schemas-compile
  33   make
  34 }
  35
  36 package() {
  37   cd $pkgname
  38   make DESTDIR="$pkgdir" install
  39   install -Dt "$pkgdir/usr/share/licenses/$pkgname" -m644 COPYING
  40 }