adwaita-icon-theme/repos/extra-any/PKGBUILD

   1 # Maintainer: Jan Alexander Steffens (heftig) <heftig@archlinux.org>
   2 # Contributor: Lukas Fleischer <lfleischer@archlinux.org>
   3 # Contributor: Jan de Groot <jgc@archlinux.org>
   4
   5 pkgbase=adwaita-icon-theme
   6 pkgname=(adwaita-icon-theme adwaita-cursors)
   7 pkgver=44.0
   8 pkgrel=1
   9 pkgdesc="GNOME standard icons"
  10 url="https://gitlab.gnome.org/GNOME/adwaita-icon-theme"
  11 arch=(any)
  12 license=(
  13   CCPL:by-sa
  14   LGPL3
  15 )
  16 depends=(
  17   hicolor-icon-theme
  18   gtk-update-icon-cache
  19   librsvg
  20 )
  21 makedepends=(
  22   git
  23   gtk3
  24 )
  25 _commit=a5a52e09d26ccbb28e60a253e5b6e7eb18247e16  # tags/44.0^0
  26 source=("git+https://gitlab.gnome.org/GNOME/adwaita-icon-theme.git#commit=$_commit")
  27 b2sums=('SKIP')
  28
  29 pkgver() {
  30   cd $pkgname
  31   git describe --tags | sed 's/[^-]*-g/r&/;s/-/+/g'
  32 }
  33
  34 prepare() {
  35   cd $pkgname
  36   autoreconf -fvi
  37 }
  38
  39 build() {
  40   cd $pkgname
  41   ./configure --prefix=/usr
  42   make
  43 }
  44
  45 check() {
  46   cd $pkgname
  47   make check
  48 }
  49
  50 package_adwaita-icon-theme() {
  51   depends+=(adwaita-cursors)
  52
  53   make -C $pkgname DESTDIR="$pkgdir" install
  54
  55   mkdir -p cursors/usr/share/icons/Adwaita
  56   mv {"$pkgdir",cursors}/usr/share/icons/Adwaita/cursors
  57 }
  58
  59 package_adwaita-cursors() {
  60   pkgdesc="GNOME standard cursors"
  61   depends=()
  62
  63   mv cursors/* "$pkgdir"
  64 }
  65
  66 # vim:set sw=2 sts=-1 et: