attr/trunk/PKGBUILD

   1 # Maintainer: Thomas Bächler <thomas@archlinux.org>
   2
   3 pkgname=attr
   4 pkgver=2.5.1
   5 pkgrel=3
   6 pkgdesc='Extended attribute support library for ACL support'
   7 arch=('x86_64')
   8 url='https://savannah.nongnu.org/projects/attr'
   9 license=('LGPL')
  10 depends=('glibc')
  11 makedepends=('gettext')
  12 replaces=('xfsattr')
  13 provides=('xfsattr' 'libattr.so')
  14 conflicts=('xfsattr')
  15 backup=('etc/xattr.conf')
  16 validpgpkeys=('600CD204FBCEA418BD2CA74F154343260542DF34'  # Brandon Philips <brandon@ifup.co>
  17               'B902B5271325F892AC251AD441633B9FE837F581'  # Frysinger <vapier@gentoo.org>
  18               '259B3792B3D6D319212CC4DCD5BF9FEB0313653A') # Andreas Gruenbacher <andreas.gruenbacher@gmail.com>
  19 source=("https://download.savannah.gnu.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.xz"{,.sig})
  20 sha256sums=('db448a626f9313a1a970d636767316a8da32aede70518b8050fa0de7947adc32'
  21             'SKIP')
  22
  23 prepare() {
  24   # remove the nfs entries from /etc/xattr.conf
  25   # http://lists.gnu.org/archive/html/bug-coreutils/2019-03/msg00008.html
  26   sed -i '/nfs/d' $pkgname-$pkgver/xattr.conf
  27 }
  28
  29 build() {
  30   cd $pkgname-$pkgver
  31
  32   ./configure \
  33     --libdir=/usr/lib \
  34     --libexecdir=/usr/lib \
  35     --prefix=/usr \
  36     --sysconfdir=/etc
  37   make
  38 }
  39
  40 package() {
  41   cd $pkgname-$pkgver
  42
  43   make DESTDIR="${pkgdir}" install
  44 }