botan/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2 # Contributor: Alexander F. Rødseth <xyproto@archlinux.org>
   3 # Contributor: Angel Velasquez <angvp@archlinux.org>
   4 # Contributor: Douglas Soares de Andrade <douglas@archlinux.org>
   5 # Contributor: d'Ronin <daronin@2600.com>
   6 # Contributor: Hexchain Tong <richard0053@gmail.com>
   7 # Contributor: Jack Lloyd <jack@randombit.net>
   8
   9 pkgname=botan
  10 pkgver=3.0.0
  11 pkgrel=1
  12 pkgdesc='Crypto library written in C++'
  13 arch=(x86_64)
  14 url='https://botan.randombit.net/'
  15 license=(BSD)
  16 depends=(xz sqlite)
  17 makedepends=(python boost)
  18 optdepends=('python: for using botan2.py' 'boost-libs: for the botan executable')
  19 source=(https://botan.randombit.net/releases/Botan-${pkgver}.tar.xz{,.asc})
  20 sha256sums=('5da552e00fa1c047a90c22eb5f0247ec27e7432b68b78e10a7ce0955269ccad7'
  21             'SKIP')
  22 validpgpkeys=('621DAF6411E1851C4CF9A2E16211EBF1EFBADFBC') # Botan Distribution Key
  23
  24 build() {
  25   cd ${pkgname^}-$pkgver
  26
  27   ./configure.py \
  28     --prefix=/usr \
  29     --with-bzip \
  30     --with-lzma \
  31     --with-zlib \
  32     --with-boost \
  33     --with-sqlite3 \
  34     --with-os-feature=getrandom
  35   make
  36 }
  37
  38 check() {
  39   cd ${pkgname^}-$pkgver
  40
  41   LD_LIBRARY_PATH="$PWD" ./botan-test
  42 }
  43
  44 package() {
  45   DESTDIR="$pkgdir" make -C ${pkgname^}-$pkgver install
  46   install -Dm644 ${pkgname^}-$pkgver/license.txt "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  47 }