cmake/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Andrea Scarpino <andrea@archlinux.org>
   3 # Contributor: Pierre Schmitz <pierre@archlinux.de>
   4
   5 pkgname=cmake
   6 pkgver=3.26.4
   7 pkgrel=1
   8 pkgdesc='A cross-platform open-source make system'
   9 arch=('x86_64')
  10 url="https://www.cmake.org/"
  11 license=('custom')
  12 depends=('curl' 'libarchive' 'hicolor-icon-theme' 'jsoncpp' 'libjsoncpp.so' 'libuv' 'rhash')
  13 makedepends=('qt6-base' 'python-sphinx' 'emacs')
  14 optdepends=('qt6-base: cmake-gui')
  15 source=("https://www.cmake.org/files/v${pkgver%.*}/${pkgname}-${pkgver}.tar.gz")
  16 sha512sums=('fe817c8d5e247db3f0a9a58ee37c466a47220100d9e90711cd5d06c223cef87e41d1a756e75d1537e5f8cd010dcb8971cbeab4684b1ac12bcecf84bf7b720167')
  17
  18 build() {
  19   cd ${pkgname}-${pkgver}
  20   ./bootstrap --prefix=/usr \
  21     --mandir=/share/man \
  22     --docdir=/share/doc/cmake \
  23     --datadir=/share/cmake \
  24     --sphinx-man \
  25     --sphinx-html \
  26     --system-libs \
  27     --qt-gui \
  28     --parallel=$(/usr/bin/getconf _NPROCESSORS_ONLN)
  29   make
  30 }
  31
  32 package() {
  33   cd ${pkgname}-${pkgver}
  34   make DESTDIR="${pkgdir}" install
  35
  36   rm -r "$pkgdir"/usr/share/doc/cmake/html/_sources
  37   emacs -batch -f batch-byte-compile "${pkgdir}"/usr/share/emacs/site-lisp/cmake-mode.el
  38   install -Dm644 Copyright.txt "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
  39 }