compiler-rt/repos/extra-x86_64/PKGBUILD

   1 # Maintainer: Evangelos Foutras <evangelos@foutrelis.com>
   2 # Contributor: Jan "heftig" Steffens <jan.steffens@gmail.com>
   3
   4 pkgname=compiler-rt
   5 pkgver=15.0.7
   6 pkgrel=2
   7 pkgdesc="Compiler runtime libraries for clang"
   8 arch=('x86_64')
   9 url="https://compiler-rt.llvm.org/"
  10 license=('custom:Apache 2.0 with LLVM Exception')
  11 depends=('gcc-libs')
  12 makedepends=('llvm' 'cmake' 'ninja' 'python')
  13 # Build 32-bit compiler-rt libraries on x86_64 (FS#41911)
  14 makedepends_x86_64=('lib32-gcc-libs')
  15 options=('staticlibs')
  16 _source_base=https://github.com/llvm/llvm-project/releases/download/llvmorg-$pkgver
  17 source=($_source_base/compiler-rt-$pkgver.src.tar.xz{,.sig}
  18         $_source_base/cmake-$pkgver.src.tar.xz{,.sig})
  19 sha256sums=('353832c66cce60931ea0413b3c071faad59eefa70d02c97daa8978b15e4b25b7'
  20             'SKIP'
  21             '8986f29b634fdaa9862eedda78513969fe9788301c9f2d938f4c10a3e7a3e7ea'
  22             'SKIP')
  23 validpgpkeys=('474E22316ABF4785A88C6E8EA2C794A986419D8A'  # Tom Stellard <tstellar@redhat.com>
  24               'D574BD5D1D0E98895E3BF90044F2485E45D59042') # Tobias Hieta <tobias@hieta.se>
  25
  26 prepare() {
  27   mv cmake{-$pkgver.src,}
  28   cd compiler-rt-$pkgver.src
  29   mkdir build
  30 }
  31
  32 build() {
  33   cd compiler-rt-$pkgver.src/build
  34
  35   local cmake_args=(
  36     -G Ninja
  37     -DCMAKE_BUILD_TYPE=Release
  38     -DCMAKE_INSTALL_PREFIX=/usr
  39     -DCMAKE_SKIP_RPATH=ON
  40     -DCOMPILER_RT_INSTALL_PATH=/usr/lib/clang/$pkgver
  41   )
  42   cmake .. "${cmake_args[@]}"
  43   ninja
  44 }
  45
  46 package() {
  47   cd compiler-rt-$pkgver.src/build
  48
  49   DESTDIR="$pkgdir" ninja install
  50   install -Dm644 ../LICENSE.TXT "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  51 }
  52
  53 # vim:set ts=2 sw=2 et: